mirror of
https://github.com/StepanovPlaton/Nand2Tetris.git
synced 2026-04-03 20:30:47 +04:00
64 lines
2.1 KiB
Plaintext
64 lines
2.1 KiB
Plaintext
// This file is part of www.nand2tetris.org
|
|
// and the book "The Elements of Computing Systems"
|
|
// by Nisan and Schocken, MIT Press.
|
|
// File name: projects/2/ALU.hdl
|
|
/**
|
|
* ALU (Arithmetic Logic Unit):
|
|
* Computes out = one of the following functions:
|
|
* 0, 1, -1,
|
|
* x, y, !x, !y, -x, -y,
|
|
* x + 1, y + 1, x - 1, y - 1,
|
|
* x + y, x - y, y - x,
|
|
* x & y, x | y
|
|
* on the 16-bit inputs x, y,
|
|
* according to the input bits zx, nx, zy, ny, f, no.
|
|
* In addition, computes the two output bits:
|
|
* if (out == 0) zr = 1, else zr = 0
|
|
* if (out < 0) ng = 1, else ng = 0
|
|
*/
|
|
// Implementation: Manipulates the x and y inputs
|
|
// and operates on the resulting values, as follows:
|
|
// if (zx == 1) sets x = 0 // 16-bit constant
|
|
// if (nx == 1) sets x = !x // bitwise not
|
|
// if (zy == 1) sets y = 0 // 16-bit constant
|
|
// if (ny == 1) sets y = !y // bitwise not
|
|
// if (f == 1) sets out = x + y // integer 2's complement addition
|
|
// if (f == 0) sets out = x & y // bitwise and
|
|
// if (no == 1) sets out = !out // bitwise not
|
|
|
|
CHIP ALU {
|
|
IN
|
|
x[16], y[16], // 16-bit inputs
|
|
zx, // zero the x input?
|
|
nx, // negate the x input?
|
|
zy, // zero the y input?
|
|
ny, // negate the y input?
|
|
f, // compute (out = x + y) or (out = x & y)?
|
|
no; // negate the out output?
|
|
OUT
|
|
out[16], // 16-bit output
|
|
zr, // if (out == 0) equals 1, else 0
|
|
ng; // if (out < 0) equals 1, else 0
|
|
|
|
PARTS:
|
|
Mux16(a=x, b=false, sel=zx, out=zxr);
|
|
Not16(in=zxr, out=nxr);
|
|
Mux16(a=zxr, b=nxr, sel=nx, out=xr);
|
|
|
|
Mux16(a=y, b=false, sel=zy, out=zyr);
|
|
Not16(in=zyr, out=nyr);
|
|
Mux16(a=zyr, b=nyr, sel=ny, out=yr);
|
|
|
|
Add16(a=xr, b=yr, out=s);
|
|
And16(a=xr, b=yr, out=a);
|
|
Mux16(a=a, b=s, sel=f, out=r);
|
|
|
|
Not16(in=r, out=nr);
|
|
Mux16(a=r, b=nr, sel=no, out=out, out[15]=ng, out[0..7]=r1, out[8..15]=r2);
|
|
|
|
Or8Way(in=r1, out=o1);
|
|
Or8Way(in=r2, out=o2);
|
|
Or(a=o1, b=o2, out=nzr);
|
|
Not(in=nzr, out=zr);
|
|
|
|
} |